Excel Recordset

<%
dim fname
fname=Request.QueryString("fname")

'creo una copia del template e la denomino con la variabile fname + .xls

set fs=Server.CreateObject("Scripting.FileSystemObject")
fs.CopyFile "C:\Inetpub\website\asptest\data\template.xls","C:\Inetpub\website\asptest\data\" & fname & ".xls"
set fs=nothing

set connA=Server.CreateObject("ADODB.Connection")
set connE=Server.CreateObject("ADODB.Connection")
connA.Provider="Microsoft.Jet.OLEDB.4.0"
connE.Provider="Microsoft.Jet.OLEDB.4.0;Data Source=C:\Inetpub\website\asptest\data\" & fname & ".xls;Extended Properties='Excel 8.0;HDR=Yes;IMEX=0';"
connA.Open(Server.Mappath("/asptest/data/db.mdb"))
connE.Open()

set rsA = Server.CreateObject("ADODB.recordset")
Set rsE = Server.CreateObject("ADODB.Recordset")
rsE.ActiveConnection = connE
rsE.CursorType = 3
rsE.LockType = 2
rsE.Source = "Select * from myRange"

rsA.Open "Select id, nome, cognome, reddito, data from anagrafica", connA
rsE.Open
rsE.MoveFirst

'leggo i dati da Access e li scrivo nel mio file fname.xls

do until rsA.EOF
rsE.Fields(0).Value = rsA.Fields(1).Value
rsE.Fields(1).Value = rsA.Fields(2).Value
rsE.Fields(2).Value = rsA.Fields(3).Value
rsE.Fields(3).Value = rsA.Fields(4).Value
rsE.Update

rsE.MoveNext
rsA.MoveNext
loop

rsA.close
rsE.Close
Set rsA = Nothing
Set rsE = Nothing
connA.close
connE.Close()
Set connA = Nothing
Set connE = Nothing

'rimando alla pagina nella quale eseguire il download del file

Response.Redirect("scaricaFile.asp?fname="& fname)

%>